Manufaktur industri
Industri Internet of Things | bahan industri | Pemeliharaan dan Perbaikan Peralatan | Pemrograman industri |
home  MfgRobots >> Manufaktur industri >  >> Manufacturing Technology >> Proses manufaktur

Visualisir Denyut Jantung Real-Time dengan LED Berbasis ECG

Komponen dan Perlengkapan

Alat dan Mesin yang Diperlukan

Tentang Proyek Ini

Durante bertahun-tahun saya hanya ingin membuat sesuatu dengan LED yang berkedip mengikuti detak jantung saya (dan tidak hanya saat saya berdiri sangat diam, dan masih melewatkan detak di sini dan di sana). Itu ternyata sulit, saya mencoba dan gagal selama bertahun-tahun. Tapi sekarang tidak lagi!

Semuanya diurus oleh uECG - sebuah perangkat ECG wearable kecil yang bersumber terbuka dan memiliki pin output yang ramah Arduino (pin itu naik/turun dengan setiap detak jantung). Memproses status pin ini jauh lebih mudah daripada memproses sinyal ECG, dan saya telah mencoba mendapatkan yang terbaik darinya.
UPDATE: Anda mungkin ingin memeriksa iterasi kedua dari proyek ini, yang menerima data melalui radio link.

1. Skematik
Karena kita hanya bekerja dengan sinyal digital di sini, itu sangat sederhana. Namun sebagai wearable, akan jauh lebih andal (dan lebih kecil) jika sebagian besar koneksi disolder - untuk tes cepat tidak perlu, tetapi jika Anda akan memakainya selama aktivitas berat, saya sangat merekomendasikan itu.
Skematik terlihat seperti ini:

Visualisir Denyut Jantung Real-Time dengan LED Berbasis ECG

Saya menggunakan baterai LiPo langsung sebagai input 5V - tidak ada kesalahan, jika Anda menghubungkannya ke Vin - tidak akan bekerja dengan andal (regulator tegangan di Vin memperkenalkan penurunan tegangan dan kita sama sekali tidak bisa membiarkan satu di sini). Halnya, Arduino stabil selama input tegangan tidak turun di bawah 3,4 volt. Baterai LiPo dimulai pada 4,2 volt saat penuh, dan turun ke 3,4 volt hanya ketika sisa charge kurang dari 15%. Jadi dengan baterai yang lebih besar dari ~200 mAh Anda dapat mendapatkan waktu operasi yang cukup. Selain itu, ingatlah bahwa baterai harus terhubung melalui beberapa, eh, konektor :) Karena Anda ingin melepasnya dari skematik dan mencarinya dari waktu ke waktu.

2. Kode
Program bekerja dengan cara sederhana: selalu membaca pin D3, dan saat perubahan terdetik - mendorong waktu perubahan itu ke array 20 elemen. Perbedaan antara elemen pertama dan terakhir, dibagi 20, adalah waktu rata-rata per detak (dalam milidetik). Jadi membagi 1 menit (60000 milidetik) dengan angka itu memberi kita nilai BPM. Anda dapat menyesuaikan jumlah elemen dalam array. Jumlah elemen yang lebih kecil akan menghasilkan respons lebih cepat, tetapi hasil kurang stabil (masalah apa pun dalam deteksi detak akan menyebabkan lonjakan besar dalam BPM yang dihitung). Jumlah elemen yang lebih tinggi akan memberikan data yang lebih stabil, tetapi respons lebih lambat saat BPM berubah cepat.

Lalu BPM dipetakan ke warna (biru -> hijau -> kuning -> pink -> merah saat BPM naik dari rendah ke tinggi), dan ke jumlah LED: untuk 80 BPM delapan segmen menyala, untuk 110 - sebelas dan seterusnya (skala juga dapat disesuaikan dalam kode).

#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
#include <avr/power.h>
#endif
// DI pin of LED ring
#define PIN 11
// number of pixels in the ring
#define NUMPIXELS 16
// input pin for connecting uECG
int in_pin = 3;
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);
void setup() {
pixels.begin(); // This initializes the NeoPixel library.
pinMode(in_pin, INPUT); //set pin to input mode
digitalWrite(in_pin, 1); //enable PULLUP: this is critical, uECG doesn't have internal pull-up
}
//we store last 20 heartbeats to averge BPM over them
//with higher value, it will become more reliable,
//but it will take more time to see output change when BPM changes
#define BEAT_HIST 20
long beats[BEAT_HIST];
void push_beat(long ms) //shift all beats in array and insert current one
{
for(int x = 0; x < BEAT_HIST-1; x++)
{
beats[x] = beats[x+1];
}
beats[BEAT_HIST-1] = ms;
}
int get_bpm() //using time difference between first and last beats
{
long dt = beats[BEAT_HIST-1] - beats[0];
long bpm = BEAT_HIST * 60000 / dt;
return bpm;
}
long last_pix_upd = 0; //to keep track of when we updated pixels previous time
int prev_in_state = 0; //previous state of input pin: we want to process only changes of state
void loop()
{
long ms = millis();
int in_state = digitalRead(in_pin); //1 when no beat detected, 0 in beat
if(in_state == 1 && prev_in_state == 0) //react only to change
{
push_beat(ms);
}
prev_in_state = in_state;
if(ms - last_pix_upd > 10) //don't update pixels too often
{
int r, g, b;
last_pix_upd = ms;
int bpm = get_bpm();
int max_bright = 120; //value of maximum brightness, max 255. But you don't always want it at max :)
float dd = 20; //change in BPM between color tones (blue->green->yellow->pink->red)
float t1 = 90, t2, t3, t4; //t1 - "base" BPM, lower than t1 would be blue
t2 = t1 + dd;
t3 = t2 + dd;
t4 = t3 + dd;
//code for changing color depending in which t1...t4 range we are now
if(bpm < t1){ r = 0; g = 0; b = max_bright; }
else if(bpm < t2) { r = 0; g = max_bright * (bpm-t1)/dd; b = max_bright - g; }
else if(bpm < t3) { r = max_bright * (bpm-t2)/dd; g = max_bright - r; b = r/4; }
else if(bpm < t4) { r = max_bright; g = 0; b = max_bright/2 - max_bright * (bpm-t3)/(2*dd); }
else {r = max_bright; g = 0; b = 0; }
if(in_state) //when not in beat, 1/4 intensity, so only beats are highlighted
{
r *= 0.25;
g *= 0.25;
b *= 0.25;
}
int on_pixels = (bpm+5)/10; //number of used LEDs: for 60 BPM, 6 LEDs will be on, for 120 - 12 etc
for(int i=0;i<NUMPIXELS;i++)
{
if(i < on_pixels) pixels.setPixelColor(i, pixels.Color(r,g,b));
else pixels.setPixelColor(i, pixels.Color(0,0,0)); //turn off all other LEDs
}
pixels.show();
}
}

3. Pengaturan sebagai Wearable
Nyaman untuk menempatkan Arduino di dalam lingkaran - ukurannya hampir cocok sempurna. Baterai juga pas di dekatnya. Jangan lupa bahwa uECG ditempatkan di dada - jadi Anda perlu kabel dengan konektor, pertama Anda menempatkannya, lalu Anda mengenakan kemeja dengan komponen lain, lalu Anda memasukkan konektor. Jika tidak, akan sangat tidak nyaman untuk memakainya - percayalah pada saya, saya mencoba ))

Visualisir Denyut Jantung Real-Time dengan LED Berbasis ECG
Visualisir Denyut Jantung Real-Time dengan LED Berbasis ECG
Visualisir Denyut Jantung Real-Time dengan LED Berbasis ECG

Itu dasarnya - jika semuanya dilakukan dengan benar, dalam 30 detik setelah Anda mencabut semua konektor, itu akan mulai berkedip dan menunjukkan BPM.

4. Pengujian Lapangan
Saya mengujinya saat berjalan dan berlari - dan menemukan bahwa saat berlari, baterai memantul di atas sensor ECG, merusak pembacaannya. Ketika saya memindahkannya sedikit, ternyata kabel yang menghubungkan uECG dengan Arduino terlalu pendek dan menarik sensor ECG dengan setiap langkah, merusak pembacaannya lagi. Secara keseluruhan, saya hanya mendapatkan detak yang andal saat berjalan dan berdiri, tetapi tidak saat berlari - namun saya pikir saya akan memperbaiki itu. Sensor itu sendiri, saat saya menggunakannya dengan kemeja yang berbeda, menampilkan BPM dengan benar saat berlari juga (dicek melalui aplikasinya).

Juga, ternyata LED di dada mungkin terlihat keren tetapi secara praktis berguna tidak. Sangat tidak nyaman untuk melihat ke bawah untuk memeriksa nadi Anda. Saya pikir pada iterasi selanjutnya saya akan membuat beberapa macam gelang pergelangan tangan yang akan menunjukkan detak.

P.S. Jika Anda tertarik pada proyek uECG - Anda dapat memeriksa halaman hackaday-nya, ada banyak detail teknis, desain PCB, diskusi dan log proyek.

Code

uECG_pixel_ring.inoArduino
#include <Adafruit_NeoPixel.h> #ifdef __AVR__ #include <avr/power.h> #endif // DI pin of LED ring #define PIN 11 // number of pixels in the ring #define NUMPIXELS 16 // input pin for connecting uECG int in_pin = 3; Adafruit_NeoPixel pixels = Adafruit_NeoPixel(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800); void setup() { pixels.begin(); // This initializes the NeoPixel library. pinMode(in_pin, INPUT); //set pin to input mode digitalWrite(in_pin, 1); //enable PULLUP: this is critical, uECG doesn't have internal pull-up } //we store last 20 heartbeats to averge BPM over them //with higher value, it will become more reliable, //but it will take more time to see output change when BPM changes #define BEAT_HIST 20 long beats[BEAT_HIST]; void push_beat(long ms) //shift all beats in array and insert current one { for(int x = 0; x < BEAT_HIST-1; x++) { beats[x] = beats[x+1]; } beats[BEAT_HIST-1] = ms; } int get_bpm() //using time difference between first and last beats { long dt = beats[BEAT_HIST-1] - beats[0]; long bpm = BEAT_HIST * 60000 / dt; return bpm; } long last_pix_upd = 0; //to keep track of when we updated pixels previous time int prev_in_state = 0; //previous state of input pin: we want to process only changes of state void loop() { long ms = millis(); int in_state = digitalRead(in_pin); //1 when no beat detected, 0 in beat if(in_state == 1 && prev_in_state == 0) //react only to change { push_beat(ms); } prev_in_state = in_state; if(ms - last_pix_upd > 10) //don't update pixels too often { int r, g, b; last_pix_upd = ms; int bpm = get_bpm(); int max_bright = 120; //value of maximum brightness, max 255. But you don't always want it at max :) float dd = 20; //change in BPM between color tones (blue->green->yellow->pink->red) float t1 = 90, t2, t3, t4; //t1 - "base" BPM, lower than t1 would be blue t2 = t1 + dd; t3 = t2 + dd; t4 = t3 + dd; //code for changing color depending in which t1...t4 range we are now if(bpm < t1){ r = 0; g = 0; b = max_bright; } else if(bpm < t2) { r = 0; g = max_bright * (bpm-t1)/dd; b = max_bright - g; } else if(bpm < t3) { r = max_bright * (bpm-t2)/dd; g = max_bright - r; b = r/4; } else if(bpm < t4) { r = max_bright; g = 0; b = max_bright/2 - max_bright * (bpm-t3)/(2*dd); } else {r = max_bright; g = 0; b = 0; } if(in_state) //when not in beat, 1/4 intensity, so only beats are highlighted { r *= 0.25; g *= 0.25; b *= 0.25; } int on_pixels = (bpm+5)/10; //number of used LEDs: for 60 BPM, 6 LEDs will be on, for 120 - 12 etc for(int i=0;i<NUMPIXELS;i++) { if(i < on_pixels) pixels.setPixelColor(i, pixels.Color(r,g,b)); else pixels.setPixelColor(i, pixels.Color(0,0,0)); //turn off all other LEDs } pixels.show(); } } 

Skematik

Visualisir Denyut Jantung Real-Time dengan LED Berbasis ECG

Proses manufaktur

  1. Defibrillator Eksternal: Sejarah, Desain, dan Manufaktur
  2. Gilas Adonan: Dari Asal Usul Etruria hingga Kerajinan Modern
  3. Jantung Buatan: Teknologi, Sejarah, dan Peluang Masa Depan
  4. Katup Jantung Buatan: Jenis, Sejarah, dan Inovasi Masa Depan
  5. Mengontrol LED dengan Sensor Gerak PIR pada Raspberry Pi
  6. Memantau Suhu Rumah dengan Dashboard Raspberry Pi
  7. Sistem Pemantauan Detak Jantung Jarak Jauh dengan Peringatan AWS IoT
  8. Pemantauan Denyut Jantung Kontakless melalui Speaker Cerdas: Sistem Revolusioner
  9. Tatu Elektronik Berbasis Grafana untuk Pemantauan Jantung Kontinu dan Akurat
  10. Sendi Knuckle Dijelaskan: Desain, Aplikasi, dan Fitur Utama