Manufaktur industri
Industri Internet of Things | bahan industri | Pemeliharaan dan Perbaikan Peralatan | Pemrograman industri |
home  MfgRobots >> Manufaktur industri >  >> Manufacturing Technology >> Proses manufaktur

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

Komponen dan Perlengkapan

Aplikasi dan Layanan Online

Tentang Proyek Ini

Proyek ini menyajikan solusi IoT sederhana dan biaya rendah untuk memantau dan mengontrol sistem pelacak surya dual-axis cerdas guna evaluasi kinerja.

Sistem pelacak surya berbasis IoT yang diusulkan ditunjukkan dalam Gambar 1. Ini adalah pelacak surya dual-axis yang dapat berputar secara otomatis untuk melacak posisi matahari menggunakan sensor LDR, atau secara manual oleh pengguna melalui dasbor aplikasi IoT. Sistem dimulai dengan mendeteksi posisi matahari (intensitas cahaya) melalui sensor LDR dan mengirim data ke pengontrol (papan Arduino Mega). Pengontrol kemudian memproses data ini untuk mengkomando servo motor (SM1 dan SM2) yang memegang panel PV untuk berputar menuju matahari. Nilai tegangan dan arus PV yang dihasilkan, suhu dan kelembaban juga dikirim ke Arduino melalui sensor terkait. Selanjutnya, Ethernet shield, yang dipasang pada Arduino dan memungkinkan koneksi ke Internet, akan mengirim data yang telah diambil dan/atau diproses oleh Arduino ke cloud (webserver). Terakhir, data pelacak surya, termasuk sensor LDR, daya PV, suhu dan kelembaban, ditampilkan secara real-time dalam aplikasi pemantauan IoT melalui widget yang telah dibuat sebelumnya. Aplikasi pemantauan IoT dirancang menggunakan platform Cayenne myDevices. Setelah pengguna terhubung ke internet dari komputer atau smartphone, ia dapat memvisualisasikan, dalam dasbor aplikasi IoT, semua data pelacak surya dalam widget terkait. Oleh karena itu, pengguna memiliki data yang diperlukan yang terkait dengan lingkungan dan kinerja panel PV. Selain itu, dalam mode manual, servo motor akan menerima arah sudut dari widget terkait dalam dasbor. Dengan demikian, pengguna dapat mengontrol sistemnya untuk mencari kondisi lingkungan terbaik dan mengekstrak energi maksimum dari panel PV. Aplikasi IoT juga diprogram untuk mengirim pemberitahuan peringatan (SMS atau Email) ketika sensor mencapai nilai ambang yang telah ditentukan.

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

Rancangan Perangkat Keras

Seperti yang ditunjukkan dalam Gambar 2, sistem pelacak surya IoT terdiri dari panel PV, dua servo motor, empat sensor LDR, rangkaian pembagi tegangan, sensor suhu dan kelembaban, LED dan papan Arduino Mega.

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

Panel PV yang digunakan berukuran 115 mm x 85 mm dengan keluaran 1,6 W dan dapat menghasilkan tegangan hingga 6 V. Dua servo motor 180 derajat digunakan untuk memotorisasi pelacak surya dan dikontrol oleh papan Arduino melalui pin PWM 5 dan 6. Servo motor kiri-kanan (L-R) (MG996R) memutar pelacak surya pada sumbu vertikal (Timur/Barat), sementara servo motor atas-bawah (U-D) (SG90) memutar pelacak surya pada sumbu horizontal (Selatan/Utara).

Empat LDR (Cds GL5528) digunakan untuk mencermati posisi matahari dan telah dipasang di empat sudut panel. Sensor LDR dihubungkan ke Arduino melalui pin analog A0 hingga A3. LDR adalah resistor yang nilainya menurun seiring dengan meningkatnya intensitas cahaya yang jatuh pada permukaannya. Sensor LDR dirancang sebagai rangkaian pembagi tegangan seperti yang terlihat dalam Gambar 2. Tegangan keluaran pembagi dikonversi oleh mikrokontroler Arduino Mega dari nilai analog menjadi nilai digital antara 0 dan 1023. Karena Analog to Digital Converter (ADC) mikrokontroler dikodekan dalam 10 bit. Nilai resistor seri dalam rangkaian sensor LDR adalah 330 Ω.

Suhu dan kelembaban diukur melalui sensor DHT22. DHT22 memiliki termistor dan sensor kelembaban kapasitif yang terintegrasi untuk mengukur suhu dan kelembaban relatif. Rentang suhunya dari -40 hingga 80 °C dengan akurasi < ±0,5 °C, dan rentang kelembabannya dari 0 hingga 100 % dengan ±2% (Maks ±5%) akurasi. Sensor ini menggunakan satu kabel sinyal untuk transmisi data ke Arduino (pin digital 2), dan dua kabel untuk suplai daya.

Tegangan dan arus PV diukur melalui rangkaian pembagi tegangan yang juga bertindak sebagai beban dan terdiri dari dua resistor seri 10 Ohm. Keluaran rangkaian pembagi dihubungkan ke pin analog A4 Arduino. Selain itu, LED, yang terhubung ke pin digital 3, mencerminkan status mode pelacak surya (manual atau otomatis) dalam rangkaian sistem.

Arduino Mega dengan mikrokontroler ATmega2560 digunakan sebagai pengontrol tertanam yang berinteraksi dengan Arduino Ethernet shield bersama platform pemantauan. Ethernet shield, yang dipasang di atas papan Arduino, harus dihubungkan dengan router Wi-Fi (atau PC) melalui kabel RJ45 seperti yang ditunjukkan dalam Gambar 3. Ethernet Shield didasarkan pada chip Ethernet Wiznet W5100 yang menyediakan stack jaringan (IP) untuk protokol TCP dan UDP.

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

Rancangan Perangkat Lunak

a. Arduino IDE

Arduino adalah platform prototipe elektronik open source dengan perangkat keras dan lunak yang mudah digunakan. Platform Arduino menyediakan lingkungan pengembangan terpadu (IDE), yang mencakup dukungan untuk bahasa pemrograman C dan C++. Papan Arduino yang digunakan dalam pekerjaan ini diprogram oleh IDE yang berfungsi sebagai editor kode dan dari mana kode program dapat diunggah ke mikrokontroler melalui kabel USB, seperti yang dapat ditunjukkan dalam Gambar 3. Papan Arduino Mega digunakan untuk mengimplementasikan semua persyaratan perangkat lunak pelacak surya berbasis IoT.

b. myDevices Cayenne

MyDevices adalah perusahaan yang menawarkan solusi IoT. Ini menawarkan platform menyeluruh untuk IoT. Dalam proyek ini, kami akan fokus pada Cayenne, salah satu solusi dari myDevices. Alat ini memungkinkan pengembang, desainer dan insinyur untuk membangun prototipe IoT. Cayenne menggunakan protokol Message Queuing Telemetry Transport (MQTT) untuk menghubungkan setiap perangkat dengan cloud Cayenne. Setelah terhubung, pengguna dapat mengirim dan menerima data dari perangkat ke dasbor Cayenne melalui Widget yang dibuat. MQTT adalah protokol pesan publish-subscribe yang didasarkan pada protokol TCP/IP. Metodologi publish-subscribe menggunakan agen pesan yang bertanggung jawab untuk mengirim pesan ke klien. MQTT adalah API untuk mengirim informasi ke cloud Cayenne atau perangkat yang dikontrol oleh Cayenne. Agen pesan dalam koneksi ini adalah cloud, yang mengelola berbagai klien (sensor dan aktuator) yang mengirim dan menerima data.

Untuk menggunakan MQTT dengan Cayenne, kita perlu menggunakan pustaka Cayenne. Untuk Arduino, pustaka CayenneMQTT dapat diinstal dari Library Manager IDE. Untuk memprogram aplikasi IoT kami yang berbasis platform IoT Cayenne, kami akan memanfaatkan fungsi yang telah ditentukan sebelumnya. Misalnya, untuk membangun koneksi antara cloud Cayenne dan Arduino Mega yang dilengkapi modul Ethernet, kami memanggil pustaka CayenneMQTTEthernet tempat kami mendeklarasikan informasi autentikasi kami (nama pengguna, sandi dan Client ID) yang harus diperoleh dari Dasbor Cayenne. Kemudian, dalam bagian setup program, kami memanggil fungsi Cayenne.begin() untuk membangun koneksi dengan dasbor Cayenne. Untuk setiap aktuator, kami membuat fungsi dengan parameter integer antara 0 dan 31 yang secara imperatif disebut CAYENNE IN (SALURAN VIRTUAL). Untuk setiap sensor, kami membuat fungsi dengan parameter integer antara 0 dan 31 yang secara imperatif disebut CAYENNE_OUT (SALURAN_VIRTUAL). Dalam bagian loop program, kami memanggil fungsi yang telah ditentukan sebelumnya Cayenne.loop(), fungsi ini sendiri memanggil fungsi CAYENNE_OUT dan CAYENNE_IN. Saluran virtual, seperti namanya, adalah saluran yang tidak secara fisik ada, yang mengkarakterisir widget visualisasi atau perintah. Ini memungkinkan mereka untuk ditautkan dengan sensor atau aktuator yang sesuai.

c. Rancangan perangkat lunak tertanam

Perangkat lunak tertanam adalah bagian yang akan ditanamkan dalam Arduino Mega untuk berinteraksi antara modul Ethernet dan cloud Cayenne (lihat Lampiran). Ini dirancang sebagai berikut:

(i) Pelacak surya berbasis IoT memiliki dua mode fungsi: manual dan otomatis. Tombol yang dibuat dalam dasbor Cayenne memiliki peran untuk beralih antara kedua mode. Ketika tidak aktif, mode manual dipilih, jika tidak, mode otomatis. Selain itu, sebuah fungsi dirancang dalam kode Arduino yang memungkinkan pemulihan status tombol. LED dalam rangkaian sistem mencerminkan status saklar ini.

Oleh karena itu, agar pengontrol tahu mode operasi yang dipilih, kita hanya perlu menguji status pin tempat LED terhubung. Misalnya, jika status LED rendah, pengontrol akan memanggil fungsi mode manual untuk dieksekusi, jika tidak, ia akan memanggil fungsi otomatis.

(ii) Jika mode manual dipilih, pengguna dapat langsung mengontrol posisi servo motor untuk mengarahkan panel PV dari timur ke barat melalui servo motor L-R atau dari selatan ke utara melalui servo motor U-D. Kontrol dilakukan dari widget terkait servo motor dalam dasbor aplikasi IoT.

Dalam mode ini, pengontrol memanggil fungsi Cayenne.loop() yang sendiri memanggil semua fungsi CAYENNE_IN, termasuk yang terkait servo motor, untuk dieksekusi. Fungsi Cayenne.loop() juga akan memanggil semua fungsi CAYENNE_OUT, yang terkait sensor, untuk dieksekusi. Di mana data terkait sensor LDR, arus, tegangan dan daya PV, suhu dan kelembaban akan dikirim ke server sehingga dapat divisualisasikan dalam widget terkait dalam aplikasi IoT.

(iii) Jika mode otomatis dipilih, algoritma yang ditunjukkan dalam Gambar 4 akan dieksekusi. Algoritma dimulai dengan membaca nilai analog yang dikembalikan oleh sensor LDR. Kemudian, memproses data ini untuk mengkomando servo motor yang memindahkan panel PV menuju posisi matahari. Mempertimbangkan gerakan pelacak surya berdasarkan sumbu vertikal, nilai rata-rata dari dua LDR di kiri dan dua LDR di kanan dibandingkan dan jika kiri menerima lebih banyak cahaya, panel PV akan bergerak ke arah tersebut (searah jarum jam) melalui servo motor L-R. Servo motor tersebut akan berhenti ketika selisih hasilnya antara -10 dan 10. Rentang ini digunakan untuk menstabilkan pengontrol dan untuk mengurangi konsumsi daya servo motor. Jika tidak, jika kanan LDR menerima lebih banyak cahaya, panel PV akan bergerak ke arah tersebut (berlawanan arah jarum jam) melalui servo motor L-R dan akan terus berputar hingga selisih hasilnya berada dalam rentang [−10, 10]. Pendekatan yang sama digunakan untuk gerakan pelacak surya berdasarkan sumbu horizontal di mana nilai rata-rata dari dua LDR di atas dan dua LDR di bawah dibandingkan.

Seperti dalam mode otomatis, pengontrol juga akan memanggil fungsi Cayenne.loop() untuk mengirim data pelacak surya ke aplikasi IoT.

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

d. Pengembangan aplikasi pemantauan IoT

(i) Interfacing perangkat keras dengan platform IoT Cayenne

Untuk menginterfacekan perangkat keras, termasuk sensor dan aktuator, dengan platform IoT, kita perlu mengikuti langkah-langkah berikut:

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino
Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino
Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino
Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino
Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

Akhirnya, Gambar 10 menggambarkan aplikasi IoT yang dirancang untuk pemantauan data pelacak surya. Setelah koneksi dengan sistem pelacak surya terbentuk, data sensor dapat divisualisasikan pada widget terkait, mode pelacakan (otomatis atau manual) dapat dipilih dari saklar switch, serta mengontrol sudut servo motor melalui widget mereka. Data sensor juga dapat diperoleh dalam bentuk grafis dengan mengubah jenis representasi dalam pengaturannya, atau hanya dengan mengklik ikon grafik di atas widget.

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

(ii) Pembuatan peringatan

Salah satu kriteria terpenting dalam sistem pemantauan adalah kemampuannya untuk mengirim pemberitahuan peringatan untuk memberitahu pengguna ketika suatu peristiwa, yang terkait dengan perangkat yang dipantau, terjadi. Untuk itu, kami memanfaatkan salah satu fitur Cayenne untuk menambahkan peringatan ke aplikasi IoT kami, di mana kami dapat memrogram aplikasi kami untuk mengirim pemberitahuan peringatan (SMS, Email, atau keduanya) atau untuk melakukan tindakan yang ditentukan. Misalnya, peringatan suhu dibuat untuk mengirim notifikasi email kepada pengguna (atau penerima) ketika suhu yang dipantau mencapai nilai ambang, seperti yang dapat ditunjukkan dalam Gambar 11. Untuk membuat peringatan, klik “Add new...” dan pilih “Trigger”, kemudian atur peristiwa dan tindakannya dan akhirnya klik “save” untuk menambahkannya ke dasbor.

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

Prototipe

Gambar 12 menyajikan prototipe pelacak surya dalam keadaan terlepas dan terrakit. Ini terdiri dari panel PV, servo motor -R dan U-D dan sensor LDR. Panel dipasang pada servo motor U-D di satu sisi dan dengan bantalan di sisi lain untuk memastikan fleksibilitas yang lebih baik ketika pelacak surya berputar di sekitar sumbu horizontal. Rangkai dipasang pada servo motor L-R. Sensor LDR dipasang di empat sudut panel di dalam silinder berongga. Jika panel tidak tegak lurus terhadap matahari, setidaknya satu LDR akan tertutup oleh bayangan yang disebabkan oleh silinder sekitarnya. Oleh karena itu, akan ada perbedaan intensitas cahaya. Orientasi terbaik adalah ketika intensitas cahaya sama di semua sensor LDR. Gambar 13 menunjukkan seluruh prototipe sistem pelacak surya berbasis IoT, dan jelas bahwa semua komponen yang dilaporkan dalam bagian perangkat keras telah digunakan untuk membangunnya.

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino
Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

Untuk detail lebih lanjut tentang hasil yang diperoleh, lihat paper di tautan ini: https://link.springer.com/chapter/10.1007%2F978-3-030-64565-6_4

Kode

Kode tertanam dari sistem pelacak surya berbasis IoT

/***************************************************************
 PROYEK: Sistem pelacak surya berbasis IoT / perangkat lunak tertanam
 Aboubakr El Hammoumi/ aboubakr.elhammoumi@usmba.ac.ma
 ***************************************************************/
#define CAYENNE_PRINT Serial
#include <CayenneMQTTEthernet.h> //Pustaka CayenneMQTT
#include <Servo.h> //Pustaka servo motor
#include <DHT.h> //Pustaka DHT
#define DHTTYPE DHT22
#define DHTPIN 2
DHT dht(DHTPIN,DHTTYPE);
//Kredensial MQTT
char username[]="498d2d00-afe2-11ea-883c-638d8ce4c23d";
char password[]="ab4a8f92d94033c01f6e18ce1d8a84d8c304c9c4";
char clientID[]="17798a40-b968-11ea-93bf-d33a96695544";
Servo servo_x; //servo motor atas-bawah
int servoh = 0;
int servohLimitHigh = 170;
int servohLimitLow = 10;
Servo servo_z; //servo motor kiri-kanan
int servov = 0;
int servovLimitHigh = 170;
int servovLimitLow = 10;
int topl,topr,botl,botr;
int threshold_value=10;
float Vout;
void setup() {
  Serial.begin(9600);
  Cayenne.begin(username, password, clientID);
  servo_x.attach(5);
  servo_z.attach(6);
  dht.begin();
  pinMode(3,OUTPUT);
  digitalWrite(3,LOW);
}
void loop() {
  topr= analogRead(A2);
  topl= analogRead(A3);
  botl= analogRead(A4);
  botr= analogRead(A5);
  Vout=(analogRead(A1) * 5.0) / 1023;
  Serial.println(" Manual-mode");
  Cayenne.loop();
  if (digitalRead(3)==HIGH){
    Serial.println(" Automatic-mode");
    servoh = servo_x.read();
    servov = servo_z.read();
    int avgtop = (topr + topl) / 2;
    int avgbot = (botr + botl) / 2;
    int avgright = (topr + botr) / 2;
    int avgleft = (topl + botl) / 2;
    int diffhori= avgtop - avgbot;
    int diffverti= avgleft - avgright;
    /*pelacakan menurut sumbu horizontal*/
    if (abs(diffhori) <= threshold_value) {
      servo_x.write(servoh); //berhenti servo atas-bawah
    }else {
      if (diffhori > threshold_value) {
        Serial.println(" x - 2 ");
        servo_x.write(servoh -2); //putaran searah jarum jam CW
        if (servoh > servohLimitHigh) {
          servoh = servohLimitHigh;
        }
        delay(10);
      }else {
        servo_x.write(servoh +2); //CCW
        if (servoh < servohLimitLow) {
          servoh = servohLimitLow;
        }
        delay(10);
      }
    }
    /*pelacakan menurut sumbu vertikal*/
    if (abs(diffverti) <= threshold_value) {
      servo_z.write(servov); //berhenti servo kiri-kanan
    }else{
      if (diffverti > threshold_value) {
        servo_z.write(servov -2); //CW
        if (servov > servovLimitHigh) {
          servov = servovLimitHigh;
        }
        delay(10);
      }else{
        servo_z.write(servov +2); //CCW
        if (servov < servovLimitLow) {
          servov = servovLimitLow;
        }
        delay(10);
      }
    }
  }
}
// Fungsi Cayenne
CAYENNE_IN(8){
  int value = getValue.asInt();
  CAYENNE_LOG("Channel %d, pin %d, value %d", 8, 3, value);
  digitalWrite(3,value);
}
CAYENNE_IN(7){
  //servo motor atas-bawah
  if (digitalRead(3)==HIGH){
    //Mode Otomatis
  } else{
    //Mode Manual
    servo_x.write(getValue.asDouble() * 180);
  }
}
CAYENNE_IN(6){
  //servo motor kiri-kanan
  if (digitalRead(3)==HIGH){
  } else{
    servo_z.write(getValue.asDouble() * 180);
  }
}
CAYENNE_OUT(0) {
  //Arus
  float current = Vout/10;
  Cayenne.virtualWrite(0, current);
  Serial.print("Current: ");
  Serial.println(current);
}
CAYENNE_OUT(1) {
  //Tegangan
  float voltage = Vout * 2;
  Cayenne.virtualWrite(1, voltage);
  Serial.print("Voltage: ");
  Serial.println(voltage);
}
CAYENNE_OUT(2){
  //LDR Kanan Atas
  Cayenne.virtualWrite(2, topr);
}
CAYENNE_OUT(3){
  //LDR Kiri Atas
  Cayenne.virtualWrite(3,topl);
}
CAYENNE_OUT(4){
  //LDR Kiri Bawah
  Cayenne.virtualWrite(4,botl);
}
CAYENNE_OUT(5){
  //LDR Kanan Bawah
  Cayenne.virtualWrite(5,botr);
}
CAYENNE_OUT(10) {
  //Daya
  float power = (Vout * 2 * Vout)/10 ;
  Cayenne.virtualWrite(10, power);
  Serial.print("Power: ");
  Serial.println(power);
}
CAYENNE_OUT(11){
  //Suhu
  float t = dht.readTemperature();
  Cayenne.virtualWrite(11, t, TYPE_TEMPERATURE, UNIT_CELSIUS);
  Serial.print("temperature: ");
  Serial.println(t);
}
CAYENNE_OUT(12){
  //Kelembaban
  float h = dht.readHumidity();
  Cayenne.virtualWrite(12, h);
  Serial.print(" humidity: ");
  Serial.println(h);
}

Skematik

Pelacak Surya Berbasis IoT: Manajemen Energi Cerdas dengan Arduino

Proses manufaktur

  1. Apa yang Memacu Praktisi IoT? Wawasan dari Pemimpin Industri
  2. Blockchain untuk Internet of Things: Membuka Pertukaran Data Terdesentralisasi yang Aman
  3. Mengamankan Lanskap IoT: Ancaman Utama dan Solusi Strategis – Bagian 2
  4. Melindungi Masa Depan Keamanan IoT: Strategi Ahli untuk Dunia Terhubung yang Lebih Aman
  5. Berinvestasi dalam Internet of Things: Membuka Pertumbuhan dan Nilai
  6. Melacak Evolusi Sebenarnya Internet of Things
  7. IoT: Menguasai Lonjakan Data untuk Transformasi Bisnis
  8. 5 Tantangan Utama yang Dihadapi Internet of Things Saat Ini
  9. Memanfaatkan IoT Industri untuk Pertumbuhan: Melampaui Penghematan Biaya
  10. Pelacak Surya V2.0 – Sistem Pelacak Panel Surya DIY Lanjutan